irpg Community - The Great Ren'Py Library

(RenPy6.99) แม่แบบเมนูภาษาไทย

Mon, 21 Dec 2015 23:44:50 +0700

Noname01.png (Size: 339.3 KB Downloads: 31)

Noname02.png (Size: 69.11 KB Downloads: 45)

เป็นแม่แบบเมนูภาษาไทยนะครับและมีเมนูย่อยการเปลี่ยนภาษาสำรองไว้ให้ด้วย
ผมแปลได้ไม่หมดแต่ก็น่าจะช่วยเพื่อนๆผู้เริ่มต้นได้บ้าง
(โหลดที่นี่)
เมื่อโหลดเสร็จให้แตกไฟล์ไปไว้ที่ renpy-6.99.7-sdk>templates นะครับ

[Ren'Py] ระบบต่อสู้จากเกม Guardian Tales - The Behind of Light

Mon, 07 Jul 2014 10:45:38 +0700

;3

สวัสดีครับทุกท่าน พอดีมีผู้สนใจวิธีการทำระบบสู้ในเกม Guardian Tales - The Behind of Light แล้วระบบก็ไม่ได้ยากอะไร ผมก็เลยจะมาอธิบายวิธีเขียนให้ทุกท่านที่สนใจอ่านกันครับ

แปะมู้เกมกันเสียเล็กน้อย http://irpg.in.th/thread-1642.html

ขอออกตัวก่อนว่าอันที่จริงผมไม่ได้คิดเองหมด ผมประยุกต์เอาเสียมากกว่า ทุกท่านที่ได้ศึกษา Renpy มาคงได้เข้าไปศึกษาที่เว็บ thaigraph กันใช่ไหมครับ ผมก็เอามาจากที่นั้นแหละ แหะๆ ยังไงก็ขอขอบคุณท่าน NOOKFUFU2 จาก thaigraph ที่มีบทความดีๆ ให้ผมได้ศึกษาครับ ;w;

ช่วงที่พัฒนาขึ้นมานั้น ผมมีเวลาสร้างเกมจำกัดอาจจะเขียนระบบไว้ไม่ดีนัก ทุกท่านก็ลองเอาไปประยุกต์ให้ดีขึ้นแล้วกันครับ

พูดเยอะไปและ เข้าเรื่องดีกว่า. . . อาโน. . พูดเรื่องไรก่อนดีอ่ะ // โดนถีบ

หลอดพลังของตัวละคร
หลอดพลังของทั้งของตัวเอกและของมอน ผมประยุกต์มาจากบทความนี้ครับ วิธีทำ label Fight RPG

แต่ในเกมผมจะเอาแค่หลอดพลังเท่านั้น ก็เอาแต่ ui.bar มาใช้ครับ

Code:
init:

    python hide:

        def score_honor():

            if show_score:

                ui.bar(max_score_honor, score_honor,

                xmaximum=312,

                ymaximum=35,

                left_bar=Frame("honorgate_full.png", 0, 0),

                right_bar=Frame("honorgate_empty.png", 0, 0),

                thumb=None,

                thumb_shadow=None)

        config.overlay_functions.append(score_honor)

        def mon_hp():

            if show_mon:

                ui.bar(mon_max_hp, mon_hp,

                xmaximum=312,

                ymaximum=21,

                left_bar=Frame("mongate_full.png", 0, 0),

                right_bar=Frame("mongate_empty.png", 0, 0),

                thumb=None,

                thumb_shadow=None)

        config.overlay_functions.append(mon_hp)

นำ code ด้านบน วางไว้ในไฟล์ .rpy ไฟล์ใดก็ได้ แต่ต้องไม่อยู่ภายใน label screen หรือ init python ใดๆ ส่วนของผมวางไว้ล่างสุดของไฟล์ options.rpy ส่วนรูปหลอดพลังให้หาหรือสร้างเอาเองนะครับ

ui.bar() เป็นฟังก์ชันสร้าง bar ของ Renpy รายละเอียด คลิ๊ก

และมีตัวแปรควบคุมการซ่อน/แสดง หลอดพลังด้วย show_score, show_mon

วิธีใช้
ที่ไฟล์ script.rpy ประการตัวแปร max_hp และ hp ณ ปัจจุบัน สำหรับใช้ใน ui.bar เอาไว้บนสุดของไฟล์ หรือที่เดียวกับตัวแปรพวกตัวละคร(Character) และตัวแปร show_score, show_mon เป็น false เพื่อซ่อนไว้ ไม่ให้เห็นตั้งแต่เริ่มเกม (เวลาแสดงก็แค่เขียน $ show_score = True เวลาซ่อนก็เขียน $ show_score = False)

Code:
$ show_score = False

$ show_mon = False

$ max_score_honor = 100

$ score_honor = 0 

$ mon_max_hp = 100

$ mon_hp = 0

จะลดพลังของมอน ก็เขียน $ mon_hp -= 5 หรือจะเพิ่มพลังก็เขียน $ mon_hp += 5 ลงไป ($ mon_hp -= 5 กับ $ mon_hp = $ mon_hp - 5 มีความหมายเดียวกัน)
*เกมของผมพระเอกไม่ได้มีหลอดพลัง แต่เป็นแต้มเพิ่มไปเรื่อยๆ จนถึง ค่า max

ระบบสู้
ตัวอย่าง code ระบบสู้ภายในเกม พร้อมเขียนอธิบายไว้ในบรรทัด

Code:
$ show_score = True

    $ show_mon = True    

    $ mon_max_hp = 100  # เลือดทั้งหมดของมอน

    $ mon_hp = 100 # เลือด ณ ปัจจุบันของมอน

    $ actor_attack_point  = 1.0 # พลังโจมตีของตัวเอก

    $ actor_cri_point  = 2.0 # พลังโจมตีติดคริของตัวเอก

    $ mon_attack_point  = 5 # พลังโจมตีของมอน

    $ mon_cri_point  = 9 # พลังโจมตีติดคริของมอน

    $ hit = False

    $ miss = False

    speaker "FIGHT !!"  # โชว์ข้อความก่อนเข้าลูปสู้

    while mon_hp > 0:  # วนลูปไปเรื่อยๆ จนกว่าพลังมอนจะเหลือ 0

        $ show_score = False # ซ่อนหลอดพลังไว้หรือไม่อยากซ่อนก็เอาออกไป

        if miss: # อันนี้เขียนเงื่อนไขดักไว้กรณีเรากดปุ่ม HIT ไม่ทันหรือกดไม่โดน

                call expression renpy.random.choice(["mon_hit", "mon_cri"])

                # call expression เป็นการใช้เรียกใช้เหตุการณ์ ซึ่งจะไม่เหมือน jump ตรงที่หลังจากจบเหตุการณ์ที่เรียกมาใช้แล้ว จะกลับมารันเหตุการณ์เดิมต่อไป ซึ่งถ้าเป็น jump พอไปอีกเหตุการณ์หนึ่ง ก็จะจบเกมทันที 

                # renpy.random.choice() ฟังก์ชั่นแรนดอมของ Renpy

                $ miss = False

        $ hit = False

        show screen btnHit(renpy.random.randint(1, 10))

        # เข้า screen btnHit()

        # renpy.random.randint() เป็นฟังก์ชั่นแรนดอมตัวเลขของ Renpy ในที่นี้แรนดอมเลข 1 ถึง 10

        show wyvern_pic at center

        with Pause(1.0) # หยุดรอให้เวลาเรากดปุ่ม Hit ที่นี่ 

        hide screen btnHit

        if hit == False: # เข้าเงื่อนไขถ้าผู้เล่นกด Hit ไม่ทันหรือกดไม่โดน

            play sound "sound/dragonsnarl.mp3"

            $ show_score = True

            wyvern "! ! ! ! ! ! ! !"

            stop sound fadeout 0.5            

            $ miss = True

    # End while     

    $ show_score = True   

    wyvern ". . . . . . . . . . . . . . ."

การทำปุ่ม Hit
ปุ่ม Hit หรือ Critical ผมเขียนคล้ายฟังก์ชั่นเอาไว้ ให้ง่ายต่อการใช้

Code:
screen btnHit(damage):    

    if damage <= 7: # เงื่อนไขถ้าน้อยกว่าหรือเท่ากับ 7 ให้โชว์ปุ่ม Hit

        hbox:

            area (renpy.random.randint(10, 650), renpy.random.randint(10, 300), 1.0, 75)

            imagebutton:

                    idle "hit_damage.png"

                    hover "hit_damage_hover.png"

                    action ui.callsinnewcontext("actor_hit")

    else:

        hbox:

            area (renpy.random.randint(15, 650), renpy.random.randint(10, 300), 1.0, 75)

            imagebutton:

                    idle "menu/cri_damage.png"

                    hover "menu/cri_damage_hover.png"             

                    action ui.callsinnewcontext("actor_cri")  

label actor_hit:    

    show bg_blank with wflash

    with sshake

    play sound "sound/attack3.ogg"

    $ mon_hp = mon_hp - actor_attack_point

    $ score_honor += actor_attack_point

    $ hit = True

    return

label actor_cri:

    show bg_blank with wflash

    with sshake

    play sound "sound/battle3.ogg"

    $ mon_hp = mon_hp - actor_cri_point

    $ score_honor += actor_cri_point

    $ hit = True

    return

ui.callsinnewcontext() เอาไว้เรียกใช้ฟังก์ชั่น(เป็น Label) อีกทีหนึ่ง รายละเอียด คลิ๊ก

ส่วน code การโจมตีของมอน ก็เขียนเป็น label แยกไว้แบบตีธรรมดากับตีคริ ตรงนี้ผมไม่อธิบายแล้วกันฮะ เพราะน่าจะเข้าใจกัน

Code:
label mon_hit:

    show bg_blank with rflash

    with sshake

    play sound "sound/damage4.ogg"

    if score_honor >= 1:

        $ score_honor = score_honor - mon_attack_point  

    else:

        $ score_honor = 1  

    $ hit = True

    return

label mon_cri: 

    show bg_blank with rflash

    with sshake

    play sound "sound/battle1.ogg"

    if score_honor >= 1:

        $ score_honor = score_honor - mon_cri_point

    else:

        $ score_honor = 1 

    $ hit = True

    return

การเขียนระบบสู้ของผมก็มีเพียงเท่านี้ครับ ลองประยุกต์กันดูนะครับ . .

การทำภาพเคลื่อนไหวทีละเฟรม

Sun, 08 Jun 2014 21:43:33 +0700

ในกระทู้นี้จะสอนทำภาพเคลื่อนไหวแบบอนิเมทกันให้เราเตรียมภาพที่จะใช้ไว้ให้พร้อมครับยิ่งใช้ภาพเคลื่อนไหวหลายเฟรมจะทำให้การเคลื่อนไหวเนียนขึ้นตัวอย่างนี้ผมจะใช้แค่สามเฟรม

ตัวอย่างโค้ดที่ใช้

Code:
image alisa:

   "alisa1.png"

   pause .25

   "alisa2.png"

   pause .25

   "alisa3.png"

   repeat

อธิบายโค้ด

Code:
image (ชื่อตัวแปร):

   "(ชื่อภาพ.สกุลไฟล์)"

   pause .25 *คำสั่งรอเวลา 1.0 คือ 1 วินาที

   "(ชื่อภาพ.สกุลไฟล์)"

   pause .25

   "(ชื่อภาพ.สกุลไฟล์)"

   repeat คำสั่งให้เคลื่อนไหวซ้ำ

ถ้าำจะกำหนดจำนวนครั้งของการเคลื่อนไหวก้สามารถนำจำนวนที่ต้องการไปใส่ไว้หลัง repeat ได้

ถ้าจะให้เคลื่อนไหวครั้งเดียวก็ไม่ต้องใส่ repeat

สามารถประยุกต์ใช้ได้หลายอย่างครับจะให้ตัวละครเคลื่อนไหวหรือฉากเคลื่อนไหวหรือทำพวกฝน เมฆ หมอก ก็ยังได้ แต่ถ้าจะทำเมฆหรือหมอกเคลื่อนไหวแนวนอนให้ไปดูบทความเคลื่อนย้ายตำแหน่งภาพดีกว่าครับ

ตัวอย่างภาพเคลื่อนไหวจากการใช้คำสั่งจะออกมาประมาณนี้

ขอสงวนบทความไม่อนุญาตให้นำไปเผยแพร่ที่อื่นโดยไม่ได้รับอนุญาต

การทำระบบตั้งชื่อตัวละครอย่างง่าย (Name Input)

Sun, 25 May 2014 18:08:29 +0700

สำหรับ Visual Novel แนว Simulator
เพื่อสร้างอารมณ์ร่วมในการสวมบทบาท หลายๆเกมส์มักจะมอบโอกาสให้ผู้เล่นตั้งชื่อตัวละครเองได้
ฉะนั้น เราก็จะเห็นตัวละครสาวน่ารักเรียกชื่อเราเช่น "นายจะบ้าเหรอ! 'สมศักดิ์' อย่าได้เข้าใจผิดเชียวนะ!" เป็นต้น

วันนี้เราจะมาสอนวิธีการทำแบบนั้นใน Ren'Py โปรแกรมVN Engineยอดนิยมกัน

ก่อนอื่นก็เปิดไฟล์script.rpyขึ้นมา ด้วยโปรแกรมอะไรก็ได้ตามสะดวก ส่วนของผมใช้ jedit ล่ะ

จากนั้น ก็เริ่มต้นด้วยการ define ตัวละครขึ้นมาก่อน ให้มาเริ่มที่ส่วนประกาศ เหนือ label start

Code:
#การประกาศตัวแปรชื่อ สามารถเปลี่ยน m กับ my_name ได้ตามใจชอบ

define m = DynamicCharacter('my_name', color="#ff0100")

แล้วก็เขียนโค้ดดังนี้ลงไปในส่วนของตัวเกมส์

Code:
label start:

    #การตั้งชื่อตัวละคร my_name สามารถเปลี่ยนได้ตามใจชอบ คุณอาจจะเลือกคำอื่นๆเช่น player แทนตัวแปรได้ ทั้งนี้จะต้องเป็นคำเดียวกันกับคำที่คุณประกาศตัวแปรไว้ก่อนหน้านี้นะ

    $ my_name = renpy.input("โปรดตั้งชื่อตัวละครของคุณ")

    $ my_name = my_name.strip()

    #ส่วนตรงนี้ ในกรณีที่ผู้เล่นไม่ใส่ชื่อตัวละคร เราจะตั้งชื่อตัวละครแบบdefaultไว้ด้วย 

    if my_name == "":

        $ my_name="สมศักดิ์"

เสร็จแล้วครับ ไม่ยากเลยใช่ไหม ทีนี้คำว่า my_name ทุกคำในเกมส์ของคุณก็จะใช้แทนชื่อตัวละครหลักไปตลอด
เวลาจะใช้ในเกมส์ก็ให้ทำอย่างนี้

Code:
m "ผมชื่อ %(my_name)s!"

พอลองเริ่มเกมส์มา ตัวละครที่คุณ define ไว้ คือ m = my name ก็จะพูดว่า "ผมชื่อ สมศักดิ์!"

วิธีตั้งชื่อนี้สามารถใช้กับตัวแปรอะไรก็ได้ตามต้องการนะครับ หากคุณอยากให้ผู้เล่นตั้งชื่อแมว ชื่อหมา ชื่อแฟน ชื่อพ่อแม่ ก็ให้ประกาศตัวแปรอีกอันแทน my_name แล้วทำตามแบบวิธีข้างต้นโดยเปลี่ยน my_name เป็นตัวแปรอื่นตามใจชอบได้เลย

เอาละ! Lesson Complete
หวังว่าบทความนี้คงจะประโยชน์ให้แก่ผู้สนใจเอนจิ้นเรนปี้ไม่มากก็น้อยนะครับ

โอกาสหน้าพบกันใหม่ เมี้ยว

สำหรับคนที่ขี้เกียจdefineภาพทีละภาพ

Sun, 25 May 2014 14:07:10 +0700

ตามปกติแล้ว เราต้องนั่งพิมพ์ทีละบรรทัด

ตัวอย่าง

Code:
image maid nor = "maid_nor.png"

image maid dark = "maid_dark.png"

image maid full = "maid_full.png"

(สามภาพ หน้าคุณเมดธรรมดา หน้าคุณเมดมืดมน แล้วก็ภาพคุณเมดเต็มตัว)
ถ้าเกมเรามีภาพน้อยๆก็ว่าไป แต่ถ้ามีเป็นร้อยภาพก็เสียเวลาน่าดู วิธีการง่ายๆก็คือ เอาโค้ดนี้ไปแปะไว้ท้ายไฟล์ options.rpy ครับ

Code:
config.automatic_images = '_'

(อย่าลืมเคาะสเปซบาร์สี่ครั้งก่อนนะ)

คำสั่งนี้จะทำให้ Ren'py define ภาพตามชื่อไฟล์เอง (ไม่รวมนามสกุล) โดยที่ _ ในชื่อไฟล์จะกลายเป็นเว้นวรรคแทน อย่างในตัวอย่างข้างต้นนั้นก็ได้ผลแบบเดียวกันโดยไม่ต้องเสียเวลาพิมพ์เลยสักบรรทัด อย่างมากก็แค่เสียเวลาเปลี่ยนชื่อไฟล์ก่อนเอามาใช้เท่านั้น (ยังไม่ได้ลองเอง แต่เท่าที่รู้ Ren'py มันเห็นแค่ไฟล์ .jpg กับ .png เท่านั้นน่ะนะ ใครใช้.gif หรืออื่นๆอาจจะไม่ได้ผล)

การพิมพ์บทสนทนาและเพิ่มตัวละคร

Sat, 24 May 2014 15:55:42 +0700

หัวข้อนี้ไม่ยากแต่ถือเป็นหัวใจสำคัญของVNเลยก็ว่าได้ซึ่งต้องใช้เวลาทำในส่วนนี้มากที่สุดมาดูวิธีกันเลยครับ

ก่อนอื่นจะพิมพ์บทสนทนาต้องประกา่ศตัวแปรชื่อตัวละครก่อน เช่น

Code:
$ Neoz = Character('นีออส', color="FFA500")

อธิบายโค้ด
Neoz = เป็นชื่อตัวแปรตัวละครครับตั้งชื่อให้จำได้ง่ายและสะดวก
นีออส = ชื่อในวงเล็บเป็นชื่อที่จะแสดงในเกมครับ
FFA500 = โค้ดสีหาได้จากโฟโต้ช็อปหรือเสิร์ชดูตามเว็บ

*ให้ประกาศตัวแปรไว้ก่อนบรรทัด label start:

วิธีการพิมพ์บทสนทนาหลังจากเขียนชื่อตัวแปรที่เป็นตัวละครแล้วต้องใช้ "" ครอบหน้าหลังของคำพูดตามตัวอย่างเลยครับ

Neoz "แค่กๆๆ ดันโบรุ"

ต่อไปจะเป็นส่วนประกอบของการพิมพ์บทสนทนาที่เราอาจต้องใช้ในเกมนะครับ

เครื่องหมายคำพูดให้พิมพ์ \"ประโยค\"
ตัวหนา {b}ประโยค{/b}
ตัวเอียง {i}ประโยค{/i}
ขีดเส้นใต้ {s}ประโยค{/s}
กำหนดขนาดใหม่ {size==20}ประโยค{/size}
หยุดตัวอักษร {w}
หยุดตัวอักษรแบบขึ้นบรรทัดใหม่เลย {p}
กำหนดสีใหม่ {color=FFA500}ประโยค{/color}

ต้องพิมพ์ครอบประโยคทีี่ต้องการให้แสดงผลนะครับ

สงวนบทความนี้ไม่อนุญาตให้นำไปเผยแพร่ที่อื่นโดยไม่ได้รับอนุญาต

การทำให้ภาพเคลื่อนที่จากตำแหน่งหนึ่งไปอีกตำแหน่ง

Wed, 21 May 2014 18:52:16 +0700

หัวข้อนี้หมายถึงการเคลื่อนที่ภาพจากตำแหน่งหนึ่งไปอีกตำแหน่งหนึ่งไม่ใช่การทำอนิเมทแบบให้ภาพกระพริบตาหรือการทำให้ภาพเคลื่อนไหวเป็นเฟรม

ตัวอย่างโค้ด

Code:
transform fly:   

        xpos 300 ypos 182 (ตำแหน่งตั้งต้นของภาพ)

        linear 1.0 ypos 170

        linear 1.0 ypos 182

        repeat

อธิบายโค้ด
ตรงคำว่า fly เป็นชื่อตัวแปรให้ใส่อะไรก็ได้
xpos คือค่าพิกัดแกนx(แนวนอน)อ้างอิงเป็นพิกเซล
ypos คือค่าพิกัดแกนy(แนวตั้ง)อ้างอิงเป็นพิกเซล
หากจะให้อ้างอิงจากขนาดจอก็ใช้ xaligh,yaligh แทนได้ครับ ตั้งค่าตั้งแต่ 0 - 1.0

linear คือความเร็วในการเคลื่อนที่ยิ่งเยอะยิ่งช้า
หลังคำสั่ง linear ให้ใส่พิกัดที่อยากให้เปลี่ยนแปลงไปด้วยครับ
อาจใช้คำสั่ง pause ให้หยุดรอจังหวะสักพักแทรกไปก็ได้
ส่วน repeat ล่างสุดคือให้มันวนลูปซ้ำไปเรื่อยๆถ้าอยากให้มันเปลี่ยนแปลงตำแหน่งครั้งเดียวก็ไม่ต้องใส่ครับ

ตัวอย่างการแสดงผลจากคำสั่งนี้ (ในตัวอย่างมีการใช้อนิเมชั่นให้ภาพเป็นเฟรมด้วย)

(แอบโฆษณาเกมตัวเอง)

สงวนบทความนี้ไม่อนุญาตให้นำไปเผยแพร่ที่อื่นโดยไม่ได้รับอนุญาต

แถบจำกัดเวลาเลือกตอบ Renpy

Wed, 21 May 2014 18:15:59 +0700

Code:
##############################################################################

# Timer

#

# :ใช้สำหรับคำถามเลือกตอบที่ต้องการจับเวลาเหมือนในเกม Walking Dead หรือ Wolf Among Us

transform alpha_dissolve:

    alpha 0.0

    linear 0.5 alpha 1.0

    on hide:

        linear 0.5 alpha 0

    # ส่วนนี้ใช้ในงาน Fade In และ Fade Out ของแถบจับเวลา เรียกใช้เพียง 1 ครั้ง

screen countdown:

    timer time repeat False action [Hide('countdown'), Jump(timer_jump)]

# xmaximum คือความกว้างสูงสุดของแถบ ,right_bar คือภาพของแถบด้านขวา , left_bar คือภาพของแถบด้านซ้าย , thumb คือภาพหัวลูกศรที่ใช้ลากแถบ (ในที่นี้ไม่่ได้ใส่ไว้เลยเป็น None )

    bar value AnimatedValue(0, time, time, time) xmaximum 300 xalign 0.70910 yalign 0.05 right_bar "graphics/ui/timed_right_empty.png" left_bar "graphics/ui/timed_full.png"  thumb None

# ปกติแถบจะเปลี่ยนจากด้านซ้ายไปขวา (จะลดหรือเพิ่มขึ้นอยู่กับรูปด้วย) ถ้าต้องการให้กลับด้านกัน ใช้ bar_invert ดังด้านล่างนี้

    bar value AnimatedValue(0, time, time, time) xmaximum 300 xalign 0.30115 yalign 0.05 bar_invert True right_bar "graphics/ui/timed_full.png"  left_bar "graphics/ui/timed_left_empty.png" thumb None

จากตัวอย่างนี้ถ้าลองรันดูจะพบว่า แถบเวลาจะเริ่มจากปลายสุดของแต่ละด้านล้วมาบรรจบที่ตรงกลาง (ตามรูปประกอบด้านล่างนี้)

ลองเอาไปประยุกต์ใช้ดูนะครับ (ผมอธิบายไม่ค่อยเก่ง)
ไฟล์รูปจะอยู่ในไฟล์แนบนะครับ

วิธีใช้
1).แตกไฟล์ zip แล้วนำไปวางในโฟลเดอร์เกมของท่าน
2).นำ Code ด้านบน วางไว้ในไฟล์ .rpy ไฟล์ใดก็ได้ แต่ต้องไม่อยู่ภายใน label screen หรือ init python ใดๆ
(ผมวางไว้ใน screens.rpy ด้านบนสุด)
3).เวลาใช้ ใช้ใน label ทีเราเขียนเนื้อเรื่อง โดยการวาง code นี้ก่อนขึ้นคำสั่งแสดงตัวเลือก

Code:
# time คือเวลาที่ต้องการ , timer_jump คือ ข้ามไป label ชื่อ noanswer หากว่าเวลาหมดก่อนที่ผู้เล่นจะเลือกตอบคำถาม

    $ time = 15

    $ timer_jump = 'noanswer'

    show screen countdown

4).ในตัวเลือกทุกตัวเลือกต้องมีคำสั่ง hide screen countdown
ขึ้นก่อนเสมอ เมื่อปิดแถบจับเวลานี้ไป
5).เท่านี้ก็ได้แถบจับเวลาแล้ว

ตัวอย่างแถบจับเวลา (ถือโอกาสโฆษณานิดๆ >w<)

ขอบคุณครับ แล้วพบกันใหม่โอกาสหน้าสวัสดี >w<

bars.zip (Size: 2.24 KB Downloads: 9)

โปรแกรมสร้างเกม Visual novel "Renpy"

Wed, 21 May 2014 12:15:04 +0700

Ren'Py โปรแกรมสำหรับทำเกมแนว Visual Novel

ภาษาคอมพิวเตอร์ที่ใช้ในการพัฒนา Python

ระบบปฏิบัติการที่สามารถใช้รันตัวเกมส์ได้
Windows, Linux, Mac OS X, iPhone , iPad และระบบปฏิบัติการ Android ทุกรุ่น

ลิขสิทธิ์ MIT License
เว็บไซต์ผู้พัฒนา www.renpy.org
(สามารถไปอัพเดทข้อมูลและดาวน์โหลดโปรแกรมรุ่นล่าสุดได้ที่เว็บไซด์นี้)

ดาวน์โหลด Renpy ได้ที่นี่
http://www.renpy.org/latest.html

ในการรันโปรแกรมเรนปี้จำเป็นต้องใช้โปรแกรมสำหรับเขียนโค้ดด้วย เช่น jedit,editra
ซึ่งสามารถดาวน์โหลดได้จากลิงค์ด้านบนเช่นกัน

ที่สำคัญเอ็นจิ้นนี้เป็นฟรีแวร์สามารถทำขายได้เลยครับ(เฉพาะเอ็นจิ้นไม่รวมรีซอสจากที่อื่น)